1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
|
-module(fabric_rpc).
-export([get_db_info/1, get_doc_count/1, get_update_seq/1]).
-export([open_doc/3, open_revs/4, get_missing_revs/2, update_docs/3]).
-export([all_docs/2]).
-include("fabric.hrl").
-record (view_acc, {
db,
limit,
include_docs,
offset = nil,
reduce_fun = fun couch_db:enum_docs_reduce_to_count/1,
stop_fun,
group_level = 0
}).
%% rpc endpoints
%% call to with_db will supply your M:F with a #db{} and then remaining args
all_docs(DbName, #view_query_args{keys=nil} = QueryArgs) ->
{ok, Db} = couch_db:open(DbName, []),
#view_query_args{
start_key = StartKey,
start_docid = StartDocId,
limit = Limit,
skip = Skip,
include_docs = IncludeDocs,
direction = Dir
} = QueryArgs,
StartId = if is_binary(StartKey) -> StartKey; true -> StartDocId end,
Acc0 = #view_acc{
db = Db,
include_docs = IncludeDocs,
limit = Limit+Skip,
stop_fun = all_docs_stop_fun(QueryArgs)
},
{ok, Acc} = couch_db:enum_docs(Db, StartId, Dir, fun view_fold/3, Acc0),
if Acc#view_acc.offset == nil ->
Total = couch_db:get_doc_count(Db),
rexi:sync_reply({total_and_offset, Total, Total});
true -> ok end,
rexi:reply(complete).
get_db_info(DbName) ->
with_db(DbName, {couch_db, get_db_info, []}).
get_doc_count(DbName) ->
rexi:reply(case couch_db:open(DbName, []) of
{ok, Db} ->
{ok, {Count, _DelCount}} = couch_btree:full_reduce(Db#db.id_tree),
{ok, Count};
Error ->
Error
end).
get_update_seq(DbName) ->
rexi:reply(case couch_db:open(DbName, []) of
{ok, #db{update_seq = Seq}} ->
{ok, Seq};
Error ->
Error
end).
open_doc(DbName, DocId, Options) ->
with_db(DbName, {couch_db, open_doc_int, [DocId, Options]}).
open_revs(DbName, Id, Revs, Options) ->
with_db(DbName, {couch_db, open_doc_revs, [Id, Revs, Options]}).
get_missing_revs(DbName, IdRevsList) ->
% reimplement here so we get [] for Ids with no missing revs in response
rexi:reply(case couch_db:open(DbName, []) of
{ok, Db} ->
Ids = [Id1 || {Id1, _Revs} <- IdRevsList],
{ok, lists:zipwith(fun({Id, Revs}, FullDocInfoResult) ->
case FullDocInfoResult of
{ok, #full_doc_info{rev_tree=RevisionTree}} ->
{Id, couch_key_tree:find_missing(RevisionTree, Revs)};
not_found ->
{Id, Revs}
end
end, IdRevsList, couch_btree:lookup(Db#db.id_tree, Ids))};
Error ->
Error
end).
update_docs(DbName, Docs, Options) ->
with_db(DbName, {couch_db, update_docs, [Docs, Options]}).
%%
%% internal
%%
with_db(DbName, {M,F,A}) ->
case couch_db:open(DbName, []) of
{ok, Db} ->
rexi:reply(apply(M, F, [Db | A]));
Error ->
rexi:reply(Error)
end.
view_fold(#full_doc_info{} = FullDocInfo, OffsetReds, Acc) ->
% matches for _all_docs and translates #full_doc_info{} -> KV pair
case couch_doc:to_doc_info(FullDocInfo) of
#doc_info{revs=[#rev_info{deleted=false, rev=Rev}|_]} ->
Id = FullDocInfo#full_doc_info.id,
Value = {[{rev,couch_doc:rev_to_str(Rev)}]},
view_fold({{Id,Id}, Value}, OffsetReds, Acc);
#doc_info{revs=[#rev_info{deleted=true}|_]} ->
{ok, Acc}
end;
view_fold(KV, OffsetReds, #view_acc{offset=nil} = Acc) ->
% calculates the offset for this shard
#view_acc{db=Db, reduce_fun=Reduce} = Acc,
Offset = Reduce(OffsetReds),
rexi:sync_reply({total_and_offset, couch_db:get_doc_count(Db), Offset}),
view_fold(KV, OffsetReds, Acc#view_acc{offset=Offset});
view_fold(_KV, _Offset, #view_acc{limit=0} = Acc) ->
% we scanned through limit+skip local rows
{stop, Acc};
view_fold({{Key,Id}, Value}, _Offset, Acc) ->
% the normal case
#view_acc{
db = Db,
limit = Limit,
include_docs = IncludeDocs,
stop_fun = PassedEnd
} = Acc,
case PassedEnd(Key, Id) of
true ->
{stop, Acc};
false ->
RowProps = case IncludeDocs of
true ->
case couch_db:open_doc(Db, Id, []) of
{not_found, missing} ->
[{id, Id}, {key, Key}, {value, Value}, {error, missing}];
{not_found, deleted} ->
[{id, Id}, {key, Key}, {value, Value}];
{ok, Doc} ->
JsonDoc = couch_doc:to_json_obj(Doc, []),
[{id, Id}, {key, Key}, {value, Value}, {doc, JsonDoc}]
end;
false ->
[{id, Id}, {key, Key}, {value, Value}]
end,
rexi:sync_reply({row, RowProps}),
{ok, Acc#view_acc{limit=Limit-1}}
end.
all_docs_stop_fun(#view_query_args{direction=fwd, end_key=EndKey}) ->
fun(ViewKey, _) ->
couch_db_updater:less_docid(EndKey, ViewKey)
end;
all_docs_stop_fun(#view_query_args{direction=rev, end_key=EndKey}) ->
fun(ViewKey, _) ->
couch_db_updater:less_docid(ViewKey, EndKey)
end.
|
