add handler for view group _info

1 files changed, 48 insertions, 0 deletions

diff --git a/src/fabric_group_info.erl b/src/fabric_group_info.erl
new file mode 100644
index 00000000..ec716378
--- /dev/null
+++ b/src/fabric_group_info.erl
@@ -0,0 +1,48 @@
+-module(fabric_group_info).
+
+-export([go/2]).
+
+-include("fabric.hrl").
+
+go(DbName, GroupId) ->
+    {ok, DDoc} = fabric:open_doc(DbName, <<"_design/", GroupId/binary>>, []),
+    Group = couch_view_group:design_doc_to_view_group(#db{name=DbName}, DDoc),
+    Shards = partitions:all_parts(DbName),
+    Workers = fabric_util:submit_jobs(Shards, group_info, [Group]),
+    Acc0 = {fabric_dict:init(Workers, nil), []},
+    fabric_util:recv(Workers, #shard.ref, fun handle_message/3, Acc0).
+
+handle_message({ok, Info}, Shard, {Counters, Acc}) ->
+    case fabric_dict:lookup_element(Shard, Counters) of
+    undefined ->
+        % already heard from someone else in this range
+        {ok, {Counters, Acc}};
+    nil ->
+        C1 = fabric_dict:store(Shard, ok, Counters),
+        C2 = fabric_view:remove_overlapping_shards(Shard, C1),
+        case fabric_dict:any(nil, C2) of
+        true ->
+            {ok, {C2, [Info|Acc]}};
+        false ->
+            {stop, merge_results(lists:flatten([Info|Acc]))}
+        end
+    end;
+handle_message(M, _, Acc) ->
+    ?LOG_INFO("mismatch ~p", [M]),
+    {ok, Acc}.
+
+merge_results(Info) ->
+    Dict = lists:foldl(fun({K,V},D0) -> orddict:append(K,V,D0) end,
+        orddict:new(), Info),
+    orddict:fold(fun
+        (signature, [X|_], Acc) ->
+            [{signature, X} | Acc];
+        (language, [X|_], Acc) ->
+            [{language, X} | Acc];
+        (disk_size, X, Acc) ->
+            [{disk_size, lists:sum(X)} | Acc];
+        (compact_running, X, Acc) ->
+            [{compact_running, lists:member(true, X)} | Acc];
+        (_, _, Acc) ->
+            Acc
+    end, [], Dict).