class reprepro {

  case $reprepro_manage_distributions_conf {
    '': { $reprepro_manage_distributions_conf = true }
  }

  case $reprepro_manage_incoming_conf {
    '': { $reprepro_manage_incoming_conf = true }
  }

  case $reprepro_origin {
    '': { $reprepro_origin = $domain }
  }

  case $reprepro_uploaders {
    '': { fail("You need the repository uploaders! Please set \$reprepro_uploaders in your config") }
  }

  $basedir = $reprepro_basedir ? {
    ''      => '/srv/reprepro',
    default => $reprepro_basedir,
  }

  package {
    "reprepro": ensure => 'installed';
  }

  $basedir_mode = $reprepro_basedir_mode ? {
    ''      => 0771,
    default => $reprepro_basedir_mode,
  }

  $incoming_mode = $reprepro_incoming_mode ? {
    ''      => 1777,
    default => $reprepro_incoming_mode,
  }

  user { "reprepro":
    ensure => "present",
    home => "$basedir",
    gid => "reprepro",
    password => "*",
    comment => "reprepro sandbox",
    require => Group["reprepro"],
  }

  if !defined(Group["reprepro"]) {
    group { "reprepro":
      ensure => present,
    }
  }

  file {
    "$basedir":
    ensure => directory,
    mode => $basedir_mode, owner => reprepro, group => reprepro;

    "$basedir/conf":
    ensure => directory,
    mode => 0770, owner => root, group => reprepro;

    "$basedir/db":
    ensure => directory,
    mode => 0770, owner => reprepro, group => reprepro;

    "$basedir/dists":
    ensure => directory,
    mode => 0775, owner => reprepro, group => reprepro;

    "$basedir/pool":
    ensure => directory,
    mode => 0775, owner => reprepro, group => reprepro;

    "$basedir/incoming":
    ensure => directory,
    mode => $incoming_mode, owner => reprepro, group => reprepro;

    "$basedir/logs":
    ensure => directory,
    mode => 0775, owner => reprepro, group => reprepro;

    "$basedir/tmp":
    ensure => directory,
    mode => 0775, owner => reprepro, group => reprepro;

    "$basedir/conf/distributions":
    ensure => present;

    "$basedir/conf/uploaders":
    mode => 0660, owner => root, group => reprepro,
    content => template("reprepro/uploaders.erb");

    "$basedir/conf/incoming":
    ensure => present;

    "$basedir/index.html":
    mode => 0664, owner => root, group => reprepro,
    content => template("reprepro/index.html.erb");

    "$basedir/.gnupg":
    mode => 700, owner => reprepro, group => reprepro,
    ensure => directory;

    "$basedir/.gnupg/secring.gpg":
    mode => 600, owner => reprepro, group => reprepro,
    ensure => present;

    "/usr/local/bin/reprepro-export-key":
    ensure  => present,
    content => template('reprepro/reprepro-export-key.sh.erb'),
    owner   => root,
    group   => root,
    mode    => 755,
  }

  if $reprepro_manage_distributions_conf {
    File["$basedir/conf/distributions"] {
      owner   => root,
      group   => reprepro,
      mode    => 0664,
      content => template("reprepro/distributions.erb"),
    }

    exec {
      "reprepro -b $basedir createsymlinks":
        refreshonly => true,
        subscribe => File["$basedir/conf/distributions"],
        user => reprepro,
        path => "/usr/bin:/bin";
      "reprepro -b $basedir export":
        refreshonly => true,
        user => reprepro,
        subscribe => File["$basedir/conf/distributions"],
        path => "/usr/bin:/bin";
    }
  }

  if $reprepro_manage_incoming_conf {
    File["$basedir/conf/incoming"] {
      mode => 0664,
      owner => root,
      group => reprepro,
      source => "puppet://$server/modules/reprepro/incoming"
    }
  }


  exec {
    "/usr/local/bin/reprepro-export-key":
      creates     => "$basedir/key.asc",
      user        => reprepro,
      subscribe   => File["$basedir/.gnupg/secring.gpg"],
      require     => File["/usr/local/bin/reprepro-export-key"],
  }

# TODO: setup needeed lines in apache site config file

}