manifests/sources_list.pp


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

define apt::sources_list (
  $ensure = 'present',
  $source = '',
  $content = undef
) {

  if $ensure == 'present' {
    if $source == '' and $content == undef {
      fail("One of \$source or \$content must be specified for apt_sources_snippet ${name}")
    }
    if $source != '' and $content != undef {
      fail("Only one of \$source or \$content must specified for apt_sources_snippet ${name}")
    }
  }

  include apt::dot_d_directories

  # One would expect the 'file' resource on sources.list.d to trigger an
  # apt-get update when files are added or modified in the directory, but it
  # apparently doesn't.
  file { "/etc/apt/sources.list.d/${name}":
    ensure => $ensure,
    owner  => root, group => 0, mode => '0644',
    notify => Exec['refresh_apt'],
  }

  if $source {
    File["/etc/apt/sources.list.d/${name}"] {
      source => $source,
    }
  }
  else {
    File["/etc/apt/sources.list.d/${name}"] {
      content => $content,
    }
  }
}