1 files changed, 34 insertions, 0 deletions
diff --git a/puppet/modules/leap/manifests/logfile.pp b/puppet/modules/leap/manifests/logfile.pp
new file mode 100644
index 00000000..adb3ca8a
--- /dev/null
+++ b/puppet/modules/leap/manifests/logfile.pp
@@ -0,0 +1,34 @@
+#
+# make syslog log to a particular file for a particular process.
+#
+# arguments:
+#
+#   * name: what config files are named as (eg.  /etc/rsyslog.d/50-$name.conf)
+#   * log: the full path of the log file (defaults to /var/log/leap/$name.log
+#   * process: the syslog tag to filter on (defaults to name)
+#
+define leap::logfile($process = $name, $log = undef) {
+  if $log {
+    $logfile = $log
+  } else {
+    $logfile = "/var/log/leap/${name}.log"
+  }
+
+  rsyslog::snippet { "50-${name}":
+    content => template('leap/rsyslog.erb')
+  }
+
+  augeas {
+    "logrotate_${name}":
+      context => "/files/etc/logrotate.d/${name}/rule",
+      changes => [
+        "set file ${logfile}",
+        'set rotate 5',
+        'set schedule daily',
+        'set compress compress',
+        'set missingok missingok',
+        'set ifempty notifempty',
+        'set copytruncate copytruncate'
+      ]
+  }
+}