4 files changed, 169 insertions, 0 deletions
diff --git a/puppet/modules/bundler b/puppet/modules/bundler
deleted file mode 160000
-Subproject b4a4a8434616247156e59b860b47cc6256ead8d
diff --git a/puppet/modules/bundler/manifests/config.pp b/puppet/modules/bundler/manifests/config.pp
new file mode 100644
index 00000000..5937a228
--- /dev/null
+++ b/puppet/modules/bundler/manifests/config.pp
@@ -0,0 +1,74 @@
+# Define bundler::config
+#
+# All config settings for candiapp class
+#
+# == Parameters
+#
+#   [*user*]
+#     App directory owner
+#   [*config_flag*]
+#     config flag for specific gem compile settings
+#   [*app_dir*]
+#     App directory where Gemfile is located
+#   [*home_dir_base_path*]
+#     Home directory of the specified user
+#   [*use_rvm*]
+#      Sets whether rvm is used. Defaults to true
+#   [*rvm_bin*]
+#     RVM install location. Defaults to /usr/local/rvm/bin/rvm
+#   [*rvm_gem_path*]
+#     RVM gem directory. Defaults to /usr/local/rvm/gems
+#   [*rvm_gemset*]
+#     RVM gemset to use. Defaults to global.
+#   [*ruby_version*]
+#     Ruby version for RVM purposes.
+#   [*bundler_path*]
+#     Bundler install directory
+#
+# == Examples
+#
+#
+# == Requires:
+#
+#   class { bundler::install: }
+#
+define bundler::config (
+  $user,
+  $config_flag,
+  $app_dir,
+  $home_dir_base_path = $bundler::params::home_dir_base_path,
+  $use_rvm            = $bundler::params::use_rvm,
+  $rvm_bin            = $bundler::params::rvm_bin,
+  $rvm_gem_path       = $bundler::params::rvm_gem_path,
+  $rvm_gemset         = $bundler::params::rvm_gemset,
+  $ruby_version       = $bundler::ruby_version,
+  $bundler_path       = $bundler::params::bundler_path
+) {
+
+  Class['bundler::install'] -> Bundler::Config[$name]
+
+  if $user == 'root' {
+    $home_dir = '/root'
+  }
+  else {
+    $home_dir = "${home_dir_base_path}/${user}"
+  }
+
+  # Must use $bundler_path_real, otherwise cannot reassign variable error is thrown
+  if $use_rvm == 'true' {
+    $bundler_path_rvm = "${rvm_gem_path}/${ruby_version}@${rvm_gemset}/bin"
+    $bundler_bin = "${rvm_bin} ${ruby_version} exec ${bundler_path_rvm}/bundle"
+  }
+  else {
+    $bundler_bin = "${bundler_path}/bundle"
+  }
+
+  # Bundler doesn't respect uid. Use /bin/su to override this behavior for users
+  # other than root.
+  exec { "bundler_config_${name}":
+    cwd       => $app_dir,
+    command   => "/bin/su -c '${bundler_bin} config build.${name} ${config_flag} --gemfile=${app_dir}/Gemfile' ${user}",
+    unless    => "/bin/grep -i \"BUNDLE_BUILD__${name}: ${config_flag}\" ${home_dir}/.bundle/config",
+  }
+
+}
diff --git a/puppet/modules/bundler/manifests/install.pp b/puppet/modules/bundler/manifests/install.pp
new file mode 100644
index 00000000..1524de31
--- /dev/null
+++ b/puppet/modules/bundler/manifests/install.pp
@@ -0,0 +1,64 @@
+# Class bundler::install
+#
+# Installs bundler Ruby gem manager
+#
+# == Parameters
+#
+#   [*install_method*]
+#     How to install bundler, 'rvm' is the default
+#   [*ruby_version*]
+#     Ruby version that bundler will use.
+#
+# == Examples
+#
+#
+# == Requires:
+#
+#   If use_rvm = 'true':
+#   include rvm
+#
+class bundler::install (
+  $ruby_version    = undef,
+  $ensure          = 'present',
+  $install_method  = 'rvm',
+  $use_rvm         = '',
+  ) inherits bundler::params {
+
+  # deprecation warning
+  if $use_rvm != '' {
+    warning('$use_rvm is deprecated, please use $install_method instead')
+  }
+
+  if ( $install_method == undef ) or ( $install_method == 'package' ) {
+    $provider_method = undef
+  }
+  else {
+    # backwards compatibility
+    if $use_rvm == false {
+      $provider_method = gem
+    }
+    else {
+      $provider_method = $bundler::params::install_method
+    }
+  }
+
+  if $provider_method == 'rvm' {
+    if $ruby_version == undef {
+      fail('When using rvm, you must pass a ruby_version')
+    }
+    else {
+      #Install bundler with correct RVM
+      rvm_gem { 'bundler':
+        ensure       => $ensure,
+        ruby_version => $ruby_version,
+      }
+    }
+  }
+  else {
+    package { 'bundler':
+      ensure   => $ensure,
+      provider => $provider_method,
+    }
+  }
+
+}
diff --git a/puppet/modules/bundler/manifests/params.pp b/puppet/modules/bundler/manifests/params.pp
new file mode 100644
index 00000000..53ca86e4
--- /dev/null
+++ b/puppet/modules/bundler/manifests/params.pp
@@ -0,0 +1,31 @@
+# Class bundler::params
+#
+# All config settings for candiapp class
+#
+# == Parameters
+#
+#
+#
+# == Examples
+#
+#
+# == Requires:
+#
+class bundler::params {
+
+  case $::operatingsystem {
+    ubuntu, debian: {
+      $user               = 'root'
+      $home_dir_base_path = '/home'
+      $install_method     = 'rvm'
+      $rvm_bin            = '/usr/local/rvm/bin/rvm'
+      $rvm_gem_path       = '/usr/local/rvm/gems'
+      $rvm_gemset         = 'global'
+      $bundler_path       = '/usr/bin'
+    }
+    default: {
+      fail("Unsupported platform: ${::operatingsystem}")
+    }
+  }
+
+}