4 files changed, 93 insertions, 0 deletions
diff --git a/manifests/module_dir.pp b/manifests/module_dir.pp
new file mode 100644
index 00000000..2420da94
--- /dev/null
+++ b/manifests/module_dir.pp
@@ -0,0 +1,34 @@
+# common/manifests/modules_dir.pp -- create a default directory
+# for storing module specific information
+#
+# Copyright (C) 2007 David Schmitt <david@schmitt.edv-bus.at>
+# See LICENSE for the full license granted to you.
+
+# A module_dir is a storage place for all the stuff a module might want to
+# store. According to the FHS, this should go to /var/lib. Since this is a part
+# of puppet, the full path is /var/lib/puppet/modules/${name}. Every module
+# should # prefix its module_dirs with its name.
+#
+# Usage:
+# include common::moduledir
+# module_dir { ["common", "common/dir1", "common/dir2" ]: }
+#
+# You may refer to a file in module_dir by using :
+# file { "${common::moduledir::module_dir_path}/somedir/somefile": }
+define common::module_dir(
+  $owner = root,
+  $group = 0,
+  $mode = 0644
+) {
+  include common::moduledir
+  file {
+    "${common::moduledir::module_dir_path}/${name}":
+      ensure    => directory,
+      recurse   => true,
+      purge     => true,
+      force     => true,
+      owner     => $owner,
+      group     => $group,
+      mode      => $mode;
+  }
+}
diff --git a/manifests/module_file.pp b/manifests/module_file.pp
new file mode 100644
index 00000000..c1070bcf
--- /dev/null
+++ b/manifests/module_file.pp
@@ -0,0 +1,37 @@
+# common/manifests/module_file.pp -- use a modules_dir to store module
+# specific files
+#
+# Copyright (C) 2007 David Schmitt <david@schmitt.edv-bus.at>
+# See LICENSE for the full license granted to you.
+
+# Put a file into module-local storage.
+#
+# Usage:
+# common::module_file { "module/file":
+#     source => "puppet:///...",
+#     mode   => 644,   # default
+#     owner  => root,  # default
+#     group  => 0,     # default
+# }
+define common::module_file (
+  $ensure = present,
+  $source = undef,
+  $owner  = root,
+  $group  = 0,
+  $mode   = 0644
+){
+  include common::moduledir
+  file {
+    "${common::moduledir::module_dir_path}/${name}":
+      ensure  => $ensure,
+  }
+
+  if $ensure != 'absent' {
+    File["${common::moduledir::module_dir_path}/${name}"]{
+      source  => $source,
+      owner   => $owner,
+      group   => $group,
+      mode    => $mode,
+    }
+  }
+}
diff --git a/manifests/moduledir.pp b/manifests/moduledir.pp
new file mode 100644
index 00000000..f779085b
--- /dev/null
+++ b/manifests/moduledir.pp
@@ -0,0 +1,18 @@
+# setup root for module_dirs
+class common::moduledir {
+  # Use this variable to reference the base path. Thus you are safe from any
+  # changes.
+  $module_dir_path = '/var/lib/puppet/modules'
+
+  # Module programmers can use /var/lib/puppet/modules/$modulename to save
+  # module-local data, e.g. for constructing config files
+  file{$module_dir_path:
+    ensure  => directory,
+    recurse => true,
+    purge   => true,
+    force   => true,
+    owner   => root,
+    group   => 0,
+    mode    => '0755';
+  }
+}
diff --git a/manifests/moduledir/common.pp b/manifests/moduledir/common.pp
new file mode 100644
index 00000000..e74c601e
--- /dev/null
+++ b/manifests/moduledir/common.pp
@@ -0,0 +1,4 @@
+# setup a common dir
+class common::moduledir::common{
+  common::module_dir{'common': }
+}