git subrepo clone https://leap.se/git/puppet_ntp puppet/modules/ntp

subrepo:
  subdir:   "puppet/modules/ntp"
  merged:   "8a554ab"
upstream:
  origin:   "https://leap.se/git/puppet_ntp"
  branch:   "master"
  commit:   "8a554ab"
git-subrepo:
  version:  "0.3.0"
  origin:   "https://github.com/ingydotnet/git-subrepo"
  commit:   "1e79595"

Change-Id: I6132c417d321ed4f48cc3cd52d4050603fada61a

5 files changed, 224 insertions, 0 deletions

diff --git a/puppet/modules/ntp/manifests/config.pp b/puppet/modules/ntp/manifests/config.pp
new file mode 100644
index 00000000..1c8963dc
--- /dev/null
+++ b/puppet/modules/ntp/manifests/config.pp
@@ -0,0 +1,23 @@
+#
+class ntp::config inherits ntp {
+
+  if $keys_enable {
+    $directory = dirname($keys_file)
+    file { $directory:
+      ensure  => directory,
+      owner   => 0,
+      group   => 0,
+      mode    => '0755',
+      recurse => true,
+    }
+  }
+
+  file { $config:
+    ensure  => file,
+    owner   => 0,
+    group   => 0,
+    mode    => '0644',
+    content => template($config_template),
+  }
+
+}
diff --git a/puppet/modules/ntp/manifests/init.pp b/puppet/modules/ntp/manifests/init.pp
new file mode 100644
index 00000000..be951187
--- /dev/null
+++ b/puppet/modules/ntp/manifests/init.pp
@@ -0,0 +1,58 @@
+class ntp (
+  $autoupdate        = $ntp::params::autoupdate,
+  $config            = $ntp::params::config,
+  $config_template   = $ntp::params::config_template,
+  $driftfile         = $ntp::params::driftfile,
+  $keys_enable       = $ntp::params::keys_enable,
+  $keys_file         = $ntp::params::keys_file,
+  $keys_controlkey   = $ntp::params::keys_controlkey,
+  $keys_requestkey   = $ntp::params::keys_requestkey,
+  $keys_trusted      = $ntp::params::keys_trusted,
+  $package_ensure    = $ntp::params::package_ensure,
+  $package_name      = $ntp::params::package_name,
+  $panic             = $ntp::params::panic,
+  $preferred_servers = $ntp::params::preferred_servers,
+  $restrict          = $ntp::params::restrict,
+  $servers           = $ntp::params::servers,
+  $service_enable    = $ntp::params::service_enable,
+  $service_ensure    = $ntp::params::service_ensure,
+  $service_manage    = $ntp::params::service_manage,
+  $service_name      = $ntp::params::service_name,
+) inherits ntp::params {
+
+  validate_absolute_path($config)
+  validate_string($config_template)
+  validate_absolute_path($driftfile)
+  validate_bool($keys_enable)
+  validate_re($keys_controlkey, ['^\d+$', ''])
+  validate_re($keys_requestkey, ['^\d+$', ''])
+  validate_array($keys_trusted)
+  validate_string($package_ensure)
+  validate_array($package_name)
+  validate_bool($panic)
+  validate_array($preferred_servers)
+  validate_array($restrict)
+  validate_array($servers)
+  validate_bool($service_enable)
+  validate_string($service_ensure)
+  validate_bool($service_manage)
+  validate_string($service_name)
+
+  if $autoupdate {
+    notice('autoupdate parameter has been deprecated and replaced with package_ensure.  Set this to latest for the same behavior as autoupdate => true.')
+  }
+
+  include '::ntp::install'
+  include '::ntp::config'
+  include '::ntp::service'
+
+  # Anchor this as per #8040 - this ensures that classes won't float off and
+  # mess everything up.  You can read about this at:
+  # http://docs.puppetlabs.com/puppet/2.7/reference/lang_containment.html#known-issues
+  anchor { 'ntp::begin': }
+  anchor { 'ntp::end': }
+
+  Anchor['ntp::begin'] -> Class['::ntp::install'] -> Class['::ntp::config']
+    ~> Class['::ntp::service'] -> Anchor['ntp::end']
+
+}
diff --git a/puppet/modules/ntp/manifests/install.pp b/puppet/modules/ntp/manifests/install.pp
new file mode 100644
index 00000000..098949c3
--- /dev/null
+++ b/puppet/modules/ntp/manifests/install.pp
@@ -0,0 +1,9 @@
+#
+class ntp::install inherits ntp {
+
+  package { 'ntp':
+    ensure => $package_ensure,
+    name   => $package_name,
+  }
+
+}
diff --git a/puppet/modules/ntp/manifests/params.pp b/puppet/modules/ntp/manifests/params.pp
new file mode 100644
index 00000000..10a4fb2b
--- /dev/null
+++ b/puppet/modules/ntp/manifests/params.pp
@@ -0,0 +1,116 @@
+class ntp::params {
+
+  $autoupdate        = false
+  $config_template   = 'ntp/ntp.conf.erb'
+  $keys_enable       = false
+  $keys_controlkey   = ''
+  $keys_requestkey   = ''
+  $keys_trusted      = []
+  $package_ensure    = 'present'
+  $preferred_servers = []
+  $restrict          = [
+    'restrict default kod nomodify notrap nopeer noquery',
+    'restrict -6 default kod nomodify notrap nopeer noquery',
+    'restrict 127.0.0.1',
+    'restrict -6 ::1',
+  ]
+  $service_enable    = true
+  $service_ensure    = 'running'
+  $service_manage    = true
+
+  # On virtual machines allow large clock skews.
+  $panic = str2bool($::is_virtual) ? {
+    true    => false,
+    default => true,
+  }
+
+  case $::osfamily {
+    'Debian': {
+      $config          = '/etc/ntp.conf'
+      $keys_file       = '/etc/ntp/keys'
+      $driftfile       = '/var/lib/ntp/drift'
+      $package_name    = [ 'ntp' ]
+      $service_name    = 'ntp'
+      $servers         = [
+        '0.debian.pool.ntp.org iburst',
+        '1.debian.pool.ntp.org iburst',
+        '2.debian.pool.ntp.org iburst',
+        '3.debian.pool.ntp.org iburst',
+      ]
+    }
+    'RedHat': {
+      $config          = '/etc/ntp.conf'
+      $driftfile       = '/var/lib/ntp/drift'
+      $keys_file       = '/etc/ntp/keys'
+      $package_name    = [ 'ntp' ]
+      $service_name    = 'ntpd'
+      $servers         = [
+        '0.centos.pool.ntp.org',
+        '1.centos.pool.ntp.org',
+        '2.centos.pool.ntp.org',
+      ]
+    }
+    'SuSE': {
+      $config          = '/etc/ntp.conf'
+      $driftfile       = '/var/lib/ntp/drift/ntp.drift'
+      $keys_file       = '/etc/ntp/keys'
+      $package_name    = [ 'ntp' ]
+      $service_name    = 'ntp'
+      $servers         = [
+        '0.opensuse.pool.ntp.org',
+        '1.opensuse.pool.ntp.org',
+        '2.opensuse.pool.ntp.org',
+        '3.opensuse.pool.ntp.org',
+      ]
+    }
+    'FreeBSD': {
+      $config          = '/etc/ntp.conf'
+      $driftfile       = '/var/db/ntpd.drift'
+      $keys_file       = '/etc/ntp/keys'
+      $package_name    = ['net/ntp']
+      $service_name    = 'ntpd'
+      $servers         = [
+        '0.freebsd.pool.ntp.org iburst maxpoll 9',
+        '1.freebsd.pool.ntp.org iburst maxpoll 9',
+        '2.freebsd.pool.ntp.org iburst maxpoll 9',
+        '3.freebsd.pool.ntp.org iburst maxpoll 9',
+      ]
+    }
+    'Archlinux': {
+      $config          = '/etc/ntp.conf'
+      $driftfile       = '/var/lib/ntp/drift'
+      $keys_file       = '/etc/ntp/keys'
+      $package_name    = [ 'ntp' ]
+      $service_name    = 'ntpd'
+      $servers         = [
+        '0.pool.ntp.org',
+        '1.pool.ntp.org',
+        '2.pool.ntp.org',
+      ]
+    }
+    'Linux': {
+      # Account for distributions that don't have $::osfamily specific settings.
+      case $::operatingsystem {
+        'Gentoo': {
+          $config          = '/etc/ntp.conf'
+          $driftfile       = '/var/lib/ntp/drift'
+          $keys_file       = '/etc/ntp/keys'
+          $package_name    = ['net-misc/ntp']
+          $service_name    = 'ntpd'
+          $servers         = [
+            '0.gentoo.pool.ntp.org',
+            '1.gentoo.pool.ntp.org',
+            '2.gentoo.pool.ntp.org',
+            '3.gentoo.pool.ntp.org',
+          ]
+        }
+        default: {
+          fail("The ${module_name} module is not supported on an ${::operatingsystem} distribution.")
+        }
+      }
+    }
+    default: {
+      fail("The ${module_name} module is not supported on an ${::osfamily} based system.")
+    }
+  }
+}
diff --git a/puppet/modules/ntp/manifests/service.pp b/puppet/modules/ntp/manifests/service.pp
new file mode 100644
index 00000000..3f1ada0b
--- /dev/null
+++ b/puppet/modules/ntp/manifests/service.pp
@@ -0,0 +1,18 @@
+#
+class ntp::service inherits ntp {
+
+  if ! ($service_ensure in [ 'running', 'stopped' ]) {
+    fail('service_ensure parameter must be running or stopped')
+  }
+
+  if $service_manage == true {
+    service { 'ntp':
+      ensure     => $service_ensure,
+      enable     => $service_enable,
+      name       => $service_name,
+      hasstatus  => true,
+      hasrestart => true,
+    }
+  }
+
+}