Merge branch 'develop'

7 files changed, 134 insertions, 0 deletions

diff --git a/puppet/modules/nagios b/puppet/modules/nagios
deleted file mode 160000
-Subproject 68dab01a85996e14efcccf856b623a2caf25782
diff --git a/puppet/modules/nagios/manifests/nrpe/base.pp b/puppet/modules/nagios/manifests/nrpe/base.pp
new file mode 100644
index 00000000..e48e87b4
--- /dev/null
+++ b/puppet/modules/nagios/manifests/nrpe/base.pp
@@ -0,0 +1,58 @@
+# basic nrpe stuff
+class nagios::nrpe::base {
+
+  # Import all variables from entry point
+  $cfg_dir = $::nagios::nrpe::real_cfg_dir
+  $pid_file = $::nagios::nrpe::real_pid_file
+  $plugin_dir = $::nagios::nrpe::real_plugin_dir
+  $server_address = $::nagios::nrpe::server_address
+  $allowed_hosts = $::nagios::nrpe::allowed_hosts
+  $dont_blame = $::nagios::nrpe::dont_blame
+
+  package{['nagios-nrpe-server', 'nagios-plugins-basic', 'libwww-perl']:
+    ensure => installed;
+  }
+
+  # Special-case lenny. the package doesn't exist
+  if $::lsbdistcodename != 'lenny' {
+    package{'libnagios-plugin-perl': ensure => installed; }
+  }
+
+  file{
+    [ $cfg_dir, "${cfg_dir}/nrpe.d" ]:
+      ensure => directory;
+  }
+
+  file { "${cfg_dir}/nrpe.cfg":
+    content => template('nagios/nrpe/nrpe.cfg'),
+    owner   => root,
+    group   => 0,
+    mode    => '0644';
+  }
+
+  # default commands
+  nagios::nrpe::command{'basic_nrpe':
+    source => [ "puppet:///modules/site_nagios/configs/nrpe/nrpe_commands.${::fqdn}.cfg",
+                'puppet:///modules/site_nagios/configs/nrpe/nrpe_commands.cfg',
+                'puppet:///modules/nagios/nrpe/nrpe_commands.cfg' ],
+  }
+  # the check for load should be customized for each server based on number
+  # of CPUs and the type of activity.
+  $warning_1_threshold = 7 * $::processorcount
+  $warning_5_threshold = 6 * $::processorcount
+  $warning_15_threshold = 5 * $::processorcount
+  $critical_1_threshold = 10 * $::processorcount
+  $critical_5_threshold = 9 * $::processorcount
+  $critical_15_threshold = 8 * $::processorcount
+  nagios::nrpe::command {'check_load':
+    command_line => "${plugin_dir}/check_load -w ${warning_1_threshold},${warning_5_threshold},${warning_15_threshold} -c ${critical_1_threshold},${critical_5_threshold},${critical_15_threshold}",
+  }
+
+  service{'nagios-nrpe-server':
+    ensure    => running,
+    enable    => true,
+    pattern   => 'nrpe',
+    subscribe => File["${cfg_dir}/nrpe.cfg"],
+    require   => Package['nagios-nrpe-server'],
+  }
+}
diff --git a/puppet/modules/nagios/manifests/nrpe/command.pp b/puppet/modules/nagios/manifests/nrpe/command.pp
new file mode 100644
index 00000000..c66ab986
--- /dev/null
+++ b/puppet/modules/nagios/manifests/nrpe/command.pp
@@ -0,0 +1,34 @@
+# manage an nrpe command
+define nagios::nrpe::command (
+  $ensure       = present,
+  $command_line = '',
+  $source       = '',
+){
+  if ($command_line == '' and $source == '') {
+    fail('Either one of $command_line or $source must be given to nagios::nrpe::command.' )
+  }
+
+  $cfg_dir = $nagios::nrpe::real_cfg_dir
+
+  file{"${cfg_dir}/nrpe.d/${name}_command.cfg":
+    ensure  => $ensure,
+    notify  => Service['nagios-nrpe-server'],
+    require => File["${cfg_dir}/nrpe.d" ],
+    owner   => 'root',
+    group   => 0,
+    mode    => '0644';
+  }
+
+  case $source {
+    '': {
+      File["${cfg_dir}/nrpe.d/${name}_command.cfg"] {
+        content => template('nagios/nrpe/nrpe_command.erb'),
+      }
+    }
+    default: {
+      File["${cfg_dir}/nrpe.d/${name}_command.cfg"] {
+        source => $source,
+      }
+    }
+  }
+}
diff --git a/puppet/modules/nagios/manifests/nrpe/debian.pp b/puppet/modules/nagios/manifests/nrpe/debian.pp
new file mode 100644
index 00000000..fcaf8514
--- /dev/null
+++ b/puppet/modules/nagios/manifests/nrpe/debian.pp
@@ -0,0 +1,6 @@
+class nagios::nrpe::debian inherits nagios::nrpe::base {
+  include nagios::nrpe::linux
+  Service['nagios-nrpe-server'] {
+    hasstatus => false,
+  }
+}
diff --git a/puppet/modules/nagios/manifests/nrpe/freebsd.pp b/puppet/modules/nagios/manifests/nrpe/freebsd.pp
new file mode 100644
index 00000000..063b79bc
--- /dev/null
+++ b/puppet/modules/nagios/manifests/nrpe/freebsd.pp
@@ -0,0 +1,16 @@
+class nagios::nrpe::freebsd inherits nagios::nrpe::base {
+
+    Package["nagios-nrpe-server"] { name => "nrpe" }
+    Package["nagios-plugins-basic"] { name => "nagios-plugins" }
+    Package["libnagios-plugin-perl"] { name => "p5-Nagios-Plugin" }
+    Package["libwww-perl"] { name => "p5-libwww" }
+
+    # TODO check_cpustats.sh is probably not working as of now. the package 'sysstat' is not available under FreeBSD
+
+    Service["nagios-nrpe-server"] {
+        pattern => "^/usr/local/sbin/nrpe2",
+        path => "/usr/local/etc/rc.d",
+        name => "nrpe2",
+	hasstatus => "false",
+    }
+}
diff --git a/puppet/modules/nagios/manifests/nrpe/linux.pp b/puppet/modules/nagios/manifests/nrpe/linux.pp
new file mode 100644
index 00000000..14e007f3
--- /dev/null
+++ b/puppet/modules/nagios/manifests/nrpe/linux.pp
@@ -0,0 +1,9 @@
+class nagios::nrpe::linux inherits nagios::nrpe::base {
+
+    package {
+        "nagios-plugins-standard": ensure => present;
+        "ksh": ensure => present; # for check_cpustats.sh
+        "sysstat": ensure => present; # for check_cpustats.sh
+    }
+
+}
diff --git a/puppet/modules/nagios/manifests/nrpe/xinetd.pp b/puppet/modules/nagios/manifests/nrpe/xinetd.pp
new file mode 100644
index 00000000..4de0bac6
--- /dev/null
+++ b/puppet/modules/nagios/manifests/nrpe/xinetd.pp
@@ -0,0 +1,11 @@
+# This is created only to cope with cases where we're not the only ones
+# administering a machine and NRPE is running in xinetd.
+class nagios::nrpe::xinetd inherits base {
+
+    Service["nagios-nrpe-server"] {
+	    ensure    => stopped,
+    }
+
+    # TODO manage the xinetd config file that glues with NRPE
+
+}