Fixes COUCHDB-396

Makes the stats calculated over a moving window isntead of calculated for non-overlapping timeframes. This should make trend monitoring more robust.

Thanks once again to Bob Dionne for double checking this.



git-svn-id: https://svn.apache.org/repos/asf/couchdb/trunk@816043 13f79535-47bb-0310-9956-ffa450edef68

3 files changed, 323 insertions, 0 deletions

diff --git a/test/etap/120-stats-collect.t b/test/etap/120-stats-collect.t
new file mode 100644
index 00000000..463aa384
--- /dev/null
+++ b/test/etap/120-stats-collect.t
@@ -0,0 +1,150 @@
+#!/usr/bin/env escript
+%% -*- erlang -*-
+
+% Licensed under the Apache License, Version 2.0 (the "License"); you may not
+% use this file except in compliance with the License. You may obtain a copy of
+% the License at
+%
+%   http://www.apache.org/licenses/LICENSE-2.0
+%
+% Unless required by applicable law or agreed to in writing, software
+% distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+% WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+% License for the specific language governing permissions and limitations under
+% the License.
+
+main(_) ->
+    code:add_pathz("src/couchdb"),
+    etap:plan(11),
+    case (catch test()) of
+        ok ->
+            etap:end_tests();
+        Other ->
+            etap:diag(io_lib:format("Test died abnormally: ~p", [Other])),
+            etap:bail()
+    end,
+    ok.
+
+test() ->
+    couch_stats_collector:start(),
+    ok = test_counters(),
+    ok = test_abs_values(),
+    ok = test_proc_counting(),
+    ok = test_all(),
+    ok.
+
+test_counters() ->
+    AddCount = fun() -> couch_stats_collector:increment(foo) end,
+    RemCount = fun() -> couch_stats_collector:decrement(foo) end,
+    repeat(AddCount, 100),
+    repeat(RemCount, 25),
+    repeat(AddCount, 10),
+    repeat(RemCount, 5),
+    etap:is(
+        couch_stats_collector:get(foo),
+        80,
+        "Incrememnt tracks correctly."
+    ),
+
+    repeat(RemCount, 80),
+    etap:is(
+        couch_stats_collector:get(foo),
+        0,
+        "Decremented to zaro."
+    ),
+    ok.
+
+test_abs_values() ->
+    lists:map(fun(Val) ->
+        couch_stats_collector:record(bar, Val)
+    end, lists:seq(1, 15)),
+    etap:is(
+        couch_stats_collector:get(bar),
+        lists:seq(1, 15),
+        "Absolute values are recorded correctly."
+    ),
+    
+    couch_stats_collector:clear(bar),
+    etap:is(
+        couch_stats_collector:get(bar),
+        nil,
+        "Absolute values are cleared correctly."
+    ),
+    ok.
+
+test_proc_counting() ->
+    Self = self(),
+    OnePid = spawn(fun() ->
+        couch_stats_collector:track_process_count(hoopla),
+        Self ! reporting,
+        receive sepuku -> ok end
+    end),
+    R1 = erlang:monitor(process, OnePid),
+    receive reporting -> ok end,
+    etap:is(
+        couch_stats_collector:get(hoopla),
+        1,
+        "track_process_count incrememnts the counter."
+    ),
+    
+    TwicePid = spawn(fun() ->
+        couch_stats_collector:track_process_count(hoopla),
+        couch_stats_collector:track_process_count(hoopla),
+        Self ! reporting,
+        receive sepuku -> ok end
+    end),
+    R2 = erlang:monitor(process, TwicePid),
+    receive reporting -> ok end,
+    etap:is(
+        couch_stats_collector:get(hoopla),
+        3,
+        "track_process_count allows more than one incrememnt per Pid"
+    ),
+    
+    OnePid ! sepuku,
+    receive {'DOWN', R1, _, _, _} -> ok end,
+    timer:sleep(250),
+    etap:is(
+        couch_stats_collector:get(hoopla),
+        2,
+        "Process count is decremented when process exits."
+    ),
+    
+    TwicePid ! sepuku,
+    receive {'DOWN', R2, _, _, _} -> ok end,
+    timer:sleep(250),
+    etap:is(
+        couch_stats_collector:get(hoopla),
+        0,
+        "Process count is decremented for each call to track_process_count."
+    ),
+    ok.
+
+test_all() ->
+    couch_stats_collector:record(bar, 0.0),
+    couch_stats_collector:record(bar, 1.0),
+    etap:is(
+        couch_stats_collector:all(),
+        [{foo, 0}, {hoopla, 0}, {bar, [1.0, 0.0]}],
+        "all/0 returns all counters and absolute values."
+    ),
+    
+    etap:is(
+        couch_stats_collector:all(incremental),
+        [{foo, 0}, {hoopla, 0}],
+        "all/1 returns only the specified type."
+    ),
+    
+    couch_stats_collector:record(zing, 90),
+    etap:is(
+        couch_stats_collector:all(absolute),
+        [{zing, [90]}, {bar, [1.0, 0.0]}],
+        "all/1 returns only the specified type."
+    ),
+    ok.
+
+repeat(_, 0) ->
+    ok;
+repeat(Fun, Count) ->
+    Fun(),
+    repeat(Fun, Count-1).
diff --git a/test/etap/121-stats-aggregates.ini b/test/etap/121-stats-aggregates.ini
new file mode 100644
index 00000000..fc9366fc
--- /dev/null
+++ b/test/etap/121-stats-aggregates.ini
@@ -0,0 +1,8 @@
+[stats]
+rate = 10000000 ; We call collect_sample in testing
+samples = [0, 1]
+
+[stats_descriptions]
+{testing, stuff} = yay description
+{number, '11'} = randomosity
+
diff --git a/test/etap/121-stats-aggregates.t b/test/etap/121-stats-aggregates.t
new file mode 100644
index 00000000..d9130487
--- /dev/null
+++ b/test/etap/121-stats-aggregates.t
@@ -0,0 +1,165 @@
+#!/usr/bin/env escript
+%% -*- erlang -*-
+
+% Licensed under the Apache License, Version 2.0 (the "License"); you may not
+% use this file except in compliance with the License. You may obtain a copy of
+% the License at
+%
+%   http://www.apache.org/licenses/LICENSE-2.0
+%
+% Unless required by applicable law or agreed to in writing, software
+% distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+% WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+% License for the specific language governing permissions and limitations under
+% the License.
+
+main(_) ->
+    code:add_pathz("src/couchdb"),
+    etap:plan(unknown),
+    case (catch test()) of
+        ok ->
+            etap:end_tests();
+        Other ->
+            etap:diag(io_lib:format("Test died abnormally: ~p", [Other])),
+            etap:bail()
+    end,
+    ok.
+
+test() ->
+    couch_config:start_link(["test/etap/121-stats-aggregates.ini"]),
+    couch_stats_collector:start(),
+    couch_stats_aggregator:start(),
+    ok = test_all_empty(),
+    ok = test_get_empty(),
+    ok = test_count_stats(),
+    ok = test_abs_stats(),
+    ok.
+
+test_all_empty() ->
+    {Aggs} = couch_stats_aggregator:all(),
+
+    etap:is(length(Aggs), 2, "There are only two aggregate types in testing."),
+    etap:is(
+        proplists:get_value(testing, Aggs),
+        {[{stuff, make_agg(<<"yay description">>,
+            null, null, null, null, null)}]},
+        "{testing, stuff} is empty at start."
+    ),
+    etap:is(
+        proplists:get_value(number, Aggs),
+        {[{'11', make_agg(<<"randomosity">>,
+            null, null, null, null, null)}]},
+        "{number, '11'} is empty at start."
+    ),
+    ok.
+    
+test_get_empty() ->
+    etap:is(
+        couch_stats_aggregator:get_json({testing, stuff}),
+        make_agg(<<"yay description">>, null, null, null, null, null),
+        "Getting {testing, stuff} returns an empty aggregate."
+    ),
+    etap:is(
+        couch_stats_aggregator:get_json({number, '11'}),
+        make_agg(<<"randomosity">>, null, null, null, null, null),
+        "Getting {number, '11'} returns an empty aggregate."
+    ),
+    ok.
+
+test_count_stats() ->
+    lists:foreach(fun(_) ->
+        couch_stats_collector:increment({testing, stuff})
+    end, lists:seq(1, 100)),
+    couch_stats_aggregator:collect_sample(),
+    etap:is(
+        couch_stats_aggregator:get_json({testing, stuff}),
+        make_agg(<<"yay description">>, 100, 100, null, 100, 100),
+        "COUNT: Adding values changes the stats."
+    ),
+    etap:is(
+        couch_stats_aggregator:get_json({testing, stuff}, 1),
+        make_agg(<<"yay description">>, 100, 100, null, 100, 100),
+        "COUNT: Adding values changes stats for all times."
+    ),
+
+    timer:sleep(500),
+    couch_stats_aggregator:collect_sample(),
+    etap:is(
+        couch_stats_aggregator:get_json({testing, stuff}),
+        make_agg(<<"yay description">>, 100, 50, 70.711, 0, 100),
+        "COUNT: Removing values changes stats."
+    ),
+    etap:is(
+        couch_stats_aggregator:get_json({testing, stuff}, 1),
+        make_agg(<<"yay description">>, 100, 50, 70.711, 0, 100),
+        "COUNT: Removing values changes stats for all times."
+    ),
+
+    timer:sleep(600),
+    couch_stats_aggregator:collect_sample(),
+    etap:is(
+        couch_stats_aggregator:get_json({testing, stuff}),
+        make_agg(<<"yay description">>, 100, 33.333, 57.735, 0, 100),
+        "COUNT: Letting time passes doesn't remove data from time 0 aggregates"
+    ),
+    etap:is(
+        couch_stats_aggregator:get_json({testing, stuff}, 1),
+        make_agg(<<"yay description">>, 0, 0, 0, 0, 0),
+        "COUNT: Letting time pass removes data from other time aggregates."
+    ),
+    ok.
+
+test_abs_stats() ->
+    lists:foreach(fun(X) ->
+        couch_stats_collector:record({number, 11}, X)
+    end, lists:seq(0, 10)),
+    couch_stats_aggregator:collect_sample(),
+    etap:is(
+        couch_stats_aggregator:get_json({number, 11}),
+        make_agg(<<"randomosity">>, 5, 5, null, 5, 5),
+        "ABS: Adding values changes the stats."
+    ),
+    etap:is(
+        couch_stats_aggregator:get_json({number, 11}, 1),
+        make_agg(<<"randomosity">>, 5, 5, null, 5, 5),
+        "ABS: Adding values changes stats for all times."
+    ),
+
+    timer:sleep(500),
+    couch_stats_collector:record({number, 11}, 15),
+    couch_stats_aggregator:collect_sample(),
+    etap:is(
+        couch_stats_aggregator:get_json({number, 11}),
+        make_agg(<<"randomosity">>, 20, 10, 7.071, 5, 15),
+        "ABS: New values changes stats"
+    ),
+    etap:is(
+        couch_stats_aggregator:get_json({number, 11}, 1),
+        make_agg(<<"randomosity">>, 20, 10, 7.071, 5, 15),
+        "ABS: Removing values changes stats for all times."
+    ),
+
+    timer:sleep(600),
+    couch_stats_aggregator:collect_sample(),
+    etap:is(
+        couch_stats_aggregator:get_json({number, 11}),
+        make_agg(<<"randomosity">>, 20, 10, 7.071, 5, 15),
+        "ABS: Letting time passes doesn't remove data from time 0 aggregates"
+    ),
+    etap:is(
+        couch_stats_aggregator:get_json({number, 11}, 1),
+        make_agg(<<"randomosity">>, 15, 15, null, 15, 15),
+        "ABS: Letting time pass removes data from other time aggregates."
+    ),
+    ok.
+
+make_agg(Desc, Sum, Mean, StdDev, Min, Max) ->
+    {[
+        {description, Desc},
+        {current, Sum},
+        {sum, Sum},
+        {mean, Mean},
+        {stddev, StdDev},
+        {min, Min},
+        {max, Max}
+    ]}.