# add the pixelated sources and the signing key
class pixelated::apt {

  include apt

  # Use latest packages from i.e. jessie-snapshots (possibly unstable) for
  # special domains

  $version = $::domain ? {
    /^(staging|dev|unstable)\.pixelated-project\.org$/ => '-snapshots',
    /^pixelated-project.local$/                        => '-snapshots',
    default                                            => '',
  }

  apt::sources_list { 'pixelated.list':
    content => "deb [arch=amd64] http://packages.pixelated-project.org/debian ${::lsbdistcodename}${version} main\n",
    require => Exec[add_pixelated_key],
    notify  => Exec[refresh_apt],
  }

  file { '/srv/leap/0x287A1542472DC0E3_packages@pixelated-project.org.asc':
    source => 'puppet:///modules/pixelated/0x287A1542472DC0E3_packages@pixelated-project.org.asc',
    notify => Exec['add_pixelated_key']
  }
  exec{'add_pixelated_key':
    command     => '/usr/bin/apt-key add /srv/leap/0x287A1542472DC0E3_packages@pixelated-project.org.asc',
    refreshonly => true,
    require     => File['/srv/leap/0x287A1542472DC0E3_packages@pixelated-project.org.asc'],
  }

  include ::pixelated::apt::install_packages_from_pixelated
}